语言关键字

或

英文： ||
说明： 逻辑‘或’运算符，用于条件判断，遵循短路求值原则，当任一操作数为真时返回真，否则返回假，常用于条件分支和默认值设置。

' 比较两个值，如果有一方符合条件则为真
变量 a = 20
变量 b = 50
如果(a > 10 或 b < 30)
	调试输出("条件为真")
否则
	调试输出("条件为假")
结束 如果

且

英文： &&
说明： 逻辑‘与’运算符，用于条件判断，遵循短路求值原则，当所有操作数都为真时返回真，否则返回假，常用于多重条件判断。

' 比较两个值，必须两方都符合条件才为真
变量 a = 20
变量 b = 50
如果(a > 10 且 b < 100)
	调试输出("条件为真")
否则
	调试输出("条件为假")
结束 如果

空

英文： null
说明： 空值，表示有意缺少的对象值，使用‘取数据类型’ 函数返回 'object'，是 JavaScript 的历史遗留问题，用于显式表示变量未指向任何对象或值。

' 设置变量默认初始值为空
变量 a = 空
如果(a == 空)
	调试输出("a为空对象:" + 取数据类型(a))
否则
	调试输出("a不为空")
结束 如果

真

英文： true
说明： 布尔类型的真值，表示逻辑真，注意在条件判断中所有真值都会转换为‘true’，包括非空字符串、非零数字等。

' 设置变量默认初始值为真
变量 a = 真
如果(a == 真)
	调试输出("a为真")
否则
	调试输出("a不为真")
结束 如果

假

英文： false
说明： 布尔类型的假值，表示逻辑假，在条件判断中所有假值都会转换为‘false’，包括 0、空字符串、null、undefined等。

' 设置变量默认初始值为假
变量 a = 假
如果(a == 假)
	调试输出("a为假")
否则
	调试输出("a不为假")
结束 如果

类属

英文： instanceof
说明： 类型判断运算符，用于检测指定实例对象是否属于某个数据类型，语法：对象实例类属类型，返回布尔值表示是否属于该类型。

' 判断窗口中某个组件是否属于按钮类型
如果(按钮1 类属 按钮)
	调试输出("按钮1属于按钮类型")
否则
	调试输出("按钮1不属于按钮类型")
结束 如果

变量

英文： let
说明： 块级作用域变量声明关键字，声明的变量只在当前代码块内有效。

' 定义变量
变量 a = 10
调试输出(a) ' 输出10
' 定义数组
变量 b = [1,2,3]
调试输出(b) ' 输出[1,2,3]
' 定义对象
变量 c = { X:10,Y:20 }
调试输出(c)

判断

英文： switch
说明： 多分支条件语句，用于基于不同条件执行不同代码块，使用严格相等(===)进行比较，注意：该语句没有“默认”分支。

变量 时间 = 3
判断(时间)
	分支 1
		调试输出("星期一")
	分支 2
		调试输出("星期二")
	分支 3
		调试输出("星期三")
	分支 4
		调试输出("星期四")
	分支 5
		调试输出("星期五")
结束 判断

分支

英文： case
说明： 判断语句中的条件分支标记，用于指定匹配值，匹配成功后执行分支中的代码。

变量 时间 = 3
判断(时间)
	分支 1
		调试输出("星期一")
	分支 2
		调试输出("星期二")
	分支 3
		调试输出("星期三")
	分支 4
		调试输出("星期四")
	分支 5
		调试输出("星期五")
结束 判断

如果

英文： if
说明： 条件判断语句，根据条件表达式的结果决定是否执行代码块，可配合否则实现分支逻辑，是程序流程控制的基础结构。

' 条件判断
变量 a = 20
如果(a > 10)
	调试输出("a大于10")
否则
	调试输出("a不大于10")
结束 如果

否则

英文： else
说明： 条件语句的可选部分，当前面的‘如果’条件不满足时执行。

' 条件判断
变量 a = 5
如果(a > 10)
	调试输出("a大于10")
否则 如果(a < 5)
	调试输出("a小于5")
否则
	调试输出("a为其它区间值")
结束 如果

结束

英文： end
说明： 流程控制及标识函数，事件，定义等代码结束位置的关键字，用于显式指定代码块结尾。

' 结束关键字用于结束各种流程控制结构及标识语句结尾
如果(真)
	调试输出("条件为真")
结束 如果
' 标识函数结尾
函数 函数名称()
	调试输出("自定义函数")
结束 函数

退出

英文： break
说明： 退出循环控制语句，用于立即终止并退出循环。

变量 计次  = 0
判断循环(计次 < 10)
	' 当执行第5次循环的时候、提前结束并退出循环
	' 退出循环后、将不再执行后续的循环
	如果(计次 == 5)
		退出
	否则
		' 执行语句
	结束 如果
	计次 = 计次 + 1
结束循环

跳过

英文： continue
说明： 跳出循环控制语句，用于立即跳出当前这一次循环，而执行下一次（后续）的循环。

变量循环(索引 = 0,10,1)
	' 当 索引 等于 5 的时候、程序将跳过本次循环，不再执行本次循环后面的代码
	' 但下一次循环仍会继续
	如果(索引 == 5)
		跳过
	结束 如果
	调试输出("索引 = " + 索引)
结束循环

静态

英文： static
说明： 成员修饰符，在类中使用该修饰符的变量或函数，在使用时不需要创建类型或模块对象，直接使用类名调用即可。注意：网页中的普通JS脚本模块不需要静态修饰，在页面中引用脚本后，可以直接使用变量或函数。

' 使用面向对象方式在自定义类中声明静态变量或函数
定义 公用模块1 为 类
	' 定义一个静态变量，静态函数
	变量 静态 URL地址 = "http://www.vcnstudio.com"
	函数 静态 计算圆形面积(半径)
		返回 3.14 * 半径 * 半径
	结束 函数
结束 定义
' 调用静态方法，无需创建实例
变量 结果 = 公用模块1.计算圆形面积(10)
调试输出(结果)

创建

英文： new
说明： 对象实例化运算符，用于创建类型的实例对象。

' 创建一个按钮对象
变量 按钮1 = 创建 按钮()
按钮1.文本 = "点击我"
添加组件(按钮1)
调试输出(按钮1.文本)

事件

英文： event
说明： 定义接收事件语句的关键字，用于接收并处理指定组件的事件，轻语言是事件驱动语言，代码由用户操作或系统事件触发执行。

' 定义接收“按钮1被单击”的事件、回调参数请参考组件的回调接口（interface）中的事件（event）定义
事件 按钮1.被单击(源对象,事件源)
	调试输出("按钮1 被单击")
结束 事件

函数

英文： function
说明： 定义函数的关键字，创建可重复调用的代码块，支持参数、返回值等特性。

' 函数声明
函数 计算和(参数1, 参数2)
	返回 参数1 + 参数2
结束 函数
' 调用函数
变量 结果 = 计算和(10, 20)
调试输出("计算结果: " + 结果)

未定义

英文： undefined
说明： 表示声明但未赋值的变量或对象，与‘空’的区别在于‘未定义’表示未初始化，‘空’表示空对象引用。

' 声明但未赋值的变量
变量 未赋值变量
调试输出("变量值: " + 未赋值变量) ' 输出: 变量值: 未定义
调试输出("数据类型: " + 取数据类型(未赋值变量)) ' 输出: 数据类型: undefined
' 检查变量是否未定义
如果(未赋值变量 == 未定义)
	调试输出("变量确实未定义")
结束 如果

本对象

英文： this
说明： 调用上下文关键字，指向当前代码执行时的上下文对象，例如在类中调用本类中定义的变量，函数。

英文： return
说明： 函数返回语句，终止函数执行并返回指定值。

' 函数返回值或提前终止执行后续语句
函数 计算(数值)
	如果(数值 < 0)
		返回 0 ' 提前返回
	结束 如果
	返回 数值 * 2 ' 返回计算结果
结束 函数
调试输出(计算(5)) ' 输出: 10
调试输出(计算(-1)) ' 输出: 0

变量循环

英文： for
说明： 循环结构，包含初始化、循环次数和增量值三部分。支持‘退出’和‘跳过’控制循环流程，是最常用的循环结构。

' 语法：
' 参数一：初始值、指定从什么值开始循环
' 参数二：目标值、指定循环到小于哪个值就退出循环
' 参数三：递增值、每次执行循环代码后初始变量增加的值
' 示例：初始变量为0、目标值为10、每次循环后初始变量加2、当初始变量小于10时、将会退出循环。
变量循环(计次 = 0, 10, 2) ' 等效于 for (let 计次 = 0; 计次 < 10; 计次 += 2){ }
	' 循环打印输出“计次”的值
	调试输出("计次" + 计次)
结束循环

计次循环

英文：
说明： 简化版变量循环，自动处理计数变量递增，适用于已知次数的循环场景。

' 语法：
' 参数一：总循环次数、指定要循环的总次数
' 参数二：计次变量、循环递增计次的变量、每次递增加1
' 示例：循环 10 次、计次变量从 0 开始、每次计次变量加 1 、当循环 10 次后退出循环。
变量 计次 = 0
计次循环(10,计次)
	' 待循环执行的代码、循环输出 计次 变量的值
	调试输出("计次：" + 计次)
结束循环

判断循环

英文： while
说明： 判断循环，先判断条件再执行循环体，适合不确定循环次数但需要满足条件才执行的场景。

' 语法：
' 参数一：是否符合条件，如果条件为真则执行循环
' 示例：
' 当变量 计次 的值小于10时、则进入循环体内、循环执行代码块内的代码，每次执行完循环代码、让变量计次的值加1；当计次大于10时、不符合条件则不再进入循环体内、程序将跳到结束循环标志、退出循环。
变量 计次 = 0
判断循环(计次 < 10)
	' 循环执行代码、使变量的值加1
	计次 = 计次 + 1
结束循环
调试输出(计次) ' 将输出 10

结束循环

英文：
说明： 循环控制语句，用于标记循环体的结束位置，每个合法，正确的循环体语句：变量循环、计次循环、判断循环都必须使用‘结束循环’收尾。

文本型

英文： String
说明： 字符串数据类型，表示文本数据（使用引号包裹的常量内容），支持Unicode字符。

' 声明文本型变量，初始值使用引号包裹
变量 姓名 = "张三"
变量 说明 = "这是一个文本型变量示例"
' 文本拼接
变量 全名 = 姓名 + "：" + "李四"
调试输出(全名) ' 输出: 张三：李四
' 文本操作
变量 问候语 = "你好，" + 姓名 + "！"
调试输出(问候语)
' 获取文本长度（统计一串文本中有多少个字符）
变量 长度 = 取文本长度(说明)
调试输出("文本长度: " + 长度)
' 查找字符串变量中是否含有‘文本’这两个字
如果(寻找文本(说明, "文本") >= 0)
	调试输出("找到了'文本'关键词")
结束 如果

数值型

英文： number
说明： 数字数据类型，包括整数和小数，采用 IEEE 754 双精度格式存储，支持各种数学运算和类型转换。

' 声明数值型变量，支持整数，小数，负数
变量 整数 = 42
变量 小数 = 3.14159
变量 负数 = -10
' 数值运算操作
变量 和 = 整数 + 小数
变量 差 = 整数 - 10
变量 积 = 小数 * 2
变量 商 = 整数 / 3
调试输出("和: " + 和)
调试输出("差: " + 差)
调试输出("积: " + 积)
调试输出("商: " + 商)
' 数学函数运算
变量 平方根 = 取平方根(整数)
变量 绝对值 = 取绝对值(负数)
调试输出("平方根: " + 平方根)
调试输出("绝对值: " + 绝对值)

逻辑型

英文： boolean
说明： 布尔数据类型，只有‘真’和‘假’两个值，用于条件判断和逻辑运算的基础类型。

' 声明逻辑型变量
变量 a = 真
变量 b = 假
' 逻辑比较运算
变量 与运算 = a 且 b  ' 结果为假
变量 或运算 = a 或 b  ' 结果为真
变量 非运算 = (b == 假) ' 结果为真
调试输出("与运算结果: " + 与运算)
调试输出("或运算结果: " + 或运算)
调试输出("非运算结果: " + 非运算)
' 条件判断中使用逻辑型
如果(a)
	调试输出("条件为真")
结束 如果
' 函数返回逻辑型值
函数 比较数值(值1, 值2)
	返回 值1 > 值2
结束 函数
调试输出("比较结果: " + 比较数值(10, 5)) ' 输出: 比较结果: 真

对象

英文： object
说明： 对象，表示类型的实体，例如：‘按钮’为一个组件类型，‘按钮1’则表示一个按钮的实体对象。

' 创建对象
变量 人员对象 = {姓名: "张三",年龄: 30,职业: "工程师"}
' 访问对象属性
调试输出("姓名: " + 人员对象.姓名)
调试输出("年龄: " + 人员对象.年龄)
' 修改对象属性
人员对象.年龄 = 31
调试输出("新年龄: " + 人员对象.年龄)
' 对象方法
人员对象.介绍 = ()=>{
	返回 "我是" + 本对象.姓名 + "，今年" + 本对象.年龄 + "岁"
}
调试输出(人员对象.介绍())
' 创建并使用组件对象
变量 按钮1 = 创建 按钮()
按钮1.文本 = "点击我"
按钮1.置被单击回调((源对象, 事件源) => {
	调试输出("按钮被点击")
})

域变量

英文： var
说明： 声明函数作用域变量的关键字，使用该关键字定义的变量，只有在函数内部声明时才会被限制作用域；在‘如果/循环/判断’等语句块中定义的变量在其外部也可以被访问，在实际开发中不建议使用该类型变量，日常开发中应优先使用‘变量’关键字定义变量。

' 使用域变量声明
如果(真)
	域变量 a = 10
结束 如果
' 如果语句块内部声明的 a 在外部也可以被访问
调试输出(a)

输出

英文： echo
说明： 后端脚本输出内容指令，该关键字仅可用于在后端脚本中向前端页面输出内容。

' 在后端脚本中使用
输出 "这是一段后端输出的文本内容"

引用

英文： link|require_once
说明： 资源或文件引用指令，在前端页面中用于引入并使用外部的CSS/JS文件，及引用项目中自定义的JSX脚本，CSX样式文件，编译时会自动生成相应的link或script标签，在后端脚本API接口（PHP）代码中引用外部php文件，等价于：“require_once ”。

' 引用外部直链JS文件地址或样式
引用 "https://code.jquery.com/jquery-1.12.4.min.js"
引用 "https://cdn.jsdelivr.net/css/test.min.css"
' 引用项目中的自定义JSX脚本文件及CSX样式表文件
引用 "测试JS.jsx"
引用 "测试CSS.csx"
' 在后端API接口中引用外部PHP
引用 "static/lib.php"

导入

英文： use
说明： 在后端API接口中导入外部PHP文件的命名空间中的类，函数或常量。

' 导入命名空间之前，必须先引用PHP文件，外部PHP文件一般放在项目static文件夹中
引用 "static/Test.php"
' 导入这个php文件中的类，注意：如果没有命令空间，默认无需导入可以直接使用类
导入 "some\namespace\ClassA"

为

英文： as
说明： 定义变量时显示指定变量类型、虽然在JS中无需显示指定，但在轻语言中显示指定类型可以提高编译时类型安全和支持更准确的编辑时智能提示。

' 定义按钮
变量 按钮1 为 按钮
' 在页面加载完毕中创建 按钮1 的对象
事件 页面加载完毕()
	按钮1 = 创建 按钮()
	按钮1.文本 = "按钮1"
结束 事件

轻语言网站开发SDK文档